100 REMark EIDELWEISS_bas
110  REMark by S.Poole, 1990, v21mar06.
120  CLEAR: WINDOW 512,256,0,0: j1=360: j2=540: ct=1: QPC=1
130  MODE 4: i=236: m=75: SCALE 100,-75,-50: PENDOWN
140  :
150  REMark Type Speed at keyboard before running:
160  REMark for 2.8 QPC2: SLUG 10: j1=360: j2=540
170  REMark for SGC SMSQ:  SLUG 3: j1=60 : j2=90
180  REMark for SGC QDOS: no SLUG: j1=19 : j2=39
190  REMark for 128 QDOS: reduce j1 and j2 values by experiment
200 :
210  REMark Change 'ct' to current disk '_pic' number.
220  REMark Hit 's' to save _pic when QL beeps.
230  REMark Hit SPACE key to blow petals.
240  REMark (Game far best on monochrome QL monitor).
250 :
260 REPeat loop
270 :
280 REMark Fill the night sky with stars:
290  WM_PAPER 0: OVER 0: CLS
300 FOR f=1 TO RND(33 TO 99)
310     a=RND(4 TO 508): d=RND(4 TO 252)
320     e=RND(768 TO 1023): WM_BLOCK 2,2,a,d,e
330 END FOR f: CURSOR 0,i
340 :
350 REMark Rise up onto a foreground summit:
360 FOR f=1 TO m
365     rr1=RND(768 TO 1023): rr2=RND(3)
370     WM_PAPER rr1: h=RND(5): SCROLL -h
380 END FOR f: p=100: a=55: b=-a: c=35
390 :
400 REMark Draw distant mountains:
410  d=25: e=75: h=30: OVER -1
420 FOR j=1 TO RND(5 TO 9)
430     x=RND(b TO a): y=RND(a)
440     :
450     REMark Draw scree-slopes and avalanche-channels:
460     FOR f=1 TO RND(35 TO a)
470         WM_INK RND(768 TO 1023): v=RND(-c TO c)+x
480         g=RND(d TO e): w=y-g: k=v+RND(h)
490         FILL 1: LINE x,y TO v,w TO k,w TO x,y: FILL 0
500    END FOR f
510 END FOR j: OVER 0
520 :
530 REMark Draw foreground hummocks:
540  a=105: b=-a: e=25
550 FOR f=-180 TO -170 STEP RND(1 TO 3)
560     rr1=RND(768 TO 1023): rr2=RND(2): WM_INK rr1: c=RND(b TO a)
570     FILL 1: CIRCLE c,f,ABS(f)-RND(d TO e): FILL 0
580 END FOR f
590 :
600 REMark Draw eidelweiss flowers on the summit:
610  a=7: b=75: c=-a: d=1.5
620 FOR j=1 TO RND(5 TO 19)
630     L=RND(5 TO 9): x=RND(-b TO b): y=RND(-50 TO -31)
640     rr1=RND(768 TO 1023): rr2=RND(768 TO 1023): INK rr1,rr2,3
650     :
660     REMark Dont forget the numerous petals:
670     FOR f=1 TO L
680         v=x+RND(c TO a): w=y+RND(c TO a): n=RND(d TO 3)
690         e=PI/n: g=e*-1: FILL 1
700         ARC x,y TO v,w,e , x,y TO v,w,g: FILL 0
710     END FOR f: WM_INK RND(7): CIRCLE x,y,1
720 END FOR j: : u=-40: q=150
730 :
740 REMark Draw mist-layers and ambiant effects:
750  s=24: g=45: L=40: IF QPC: GO TO 830
760 FOR f=1 TO RND(2 TO 5)
770     a=RND(7): b=RND(7): c=RND(7): d=RND(7): e=RND(7)
780     RECOL a,b,c,d,e,RND(7),RND(7),RND(7): i$=INKEY$(#1,p)
790     BEEP 1234,5: i$=INKEY$(#1,200): so=i$=='s'
800     f$='flp1_Hi'&ct&'_pic'
810     IF so: SBYTES f$,131072,32767: ct=ct+1
820 END FOR f
830 :
840 REMark DANDELION-PUFF
850  j=RND(j1 TO j2): k=360/j: z=9: STRIP 0: INK 7: OVER 0
860  FILL 1: CIRCLE 0,u,z/2: FILL 0: ss=55
870  CSIZE 0,0: q$='YOU LOVE ME': r$=' NOT': s$=q$&r$
880 FOR f=1 TO j: LINE 0,u: TURNTO f*k: MOVE z: END FOR f
890 FOR f=2 TO j STEP RND(1 TO 8)
900     OVER 0: AT s,ss: CLS 4
910     IF RND(0,1): IF KEYROW(1)=64: GO TO 980
920     PRINT q$: i$=INKEY$(#1,5): AT s,ss: CLS 4: t=-1: h=f*k
930     IF RND(0,1): IF KEYROW(1)=64: GO TO 1040
940     PRINT s$: i$=INKEY$(#1,5): OVER t
950     LINE 0,u: TURNTO h: MOVE z
960 END FOR f: GO TO 1040
970 :
980 REMark HEAVENLY BLISS
990 FOR f=1 TO q STEP 2: CIRCLE g,L,f: BEEP 32000,q-f: i$=INKEY$(#1,1)
1000  FILL 1: CIRCLE g,L,25: CURSOR g,L,-65,0: OVER 0
1010  INK 0: PAPER 7: PRINT ' PARADISE! ': i$=INKEY$(#1,333)
1020  NEXT loop
1030 :
1040 REMark ABYSS OF OBLIVION
1050  a=16: b=32000: CSIZE 3,1: c$=CHR$(158): d=.75
1060 FOR f=a TO 240 STEP a
1070     AT 9,17: PRINT c$: BEEP b,f: j=(f/a)*d
1080     i$=INKEY$(#1,3): PAPER 0,RND(2),1: CLS
1090 END FOR f: i$=INKEY$(#1,100)
1100 END REPeat loop
1110 ::